将派生类型与过程从模块放置到子模块

我需要一些有关使用子模块的帮助。我的目的是使用一个子模块来表示来自父模块的特定派生类型，并且我想将派生类型的整个声明放入子模块中。例如，这是我想要转换的示例代码：

MODULE PARENT_MODULE

IMPLICIT NONE

TYPE , PUBLIC :: DERIVED_TYPE_A

  PRIVATE

  INTEGER :: I_00

  CONTAINS

  PROCEDURE , PUBLIC :: CALC_I_00 => CALC_DATA_I_00
  PROCEDURE , PUBLIC :: TAKE_I_00 => TAKE_DATA_I_00

END TYPE DERIVED_TYPE_A

PRIVATE :: CALC_DATA_I_00
PRIVATE :: TAKE_DATA_I_00

INTERFACE

  MODULE SUBROUTINE CALC_DATA_I_00( THIS , NUM_00 )

    CLASS( DERIVED_TYPE_A ) :: THIS
    INTEGER , INTENT( IN ) :: NUM_00

  END SUBROUTINE CALC_DATA_I_00

  MODULE FUNCTION TAKE_DATA_I_00( THIS ) RESULT( RES )

    CLASS( DERIVED_TYPE_A ) :: THIS
    INTEGER :: RES

  END FUNCTION TAKE_DATA_I_00

END INTERFACE

END MODULE PARENT_MODULE

SUBMODULE( PARENT_MODULE ) TYPE_A

CONTAINS

MODULE PROCEDURE CALC_DATA_I_00

  THIS%I_00 = NUM_00 + 2

END PROCEDURE CALC_DATA_I_00

MODULE PROCEDURE TAKE_DATA_I_00

  RES = THIS%I_00

END PROCEDURE TAKE_DATA_I_00

END SUBMODULE TYPE_A

PROGRAM TYPE_SUBMODULES

USE , NON_INTRINSIC :: PARENT_MODULE

IMPLICIT NONE

INTEGER :: I

CLASS( DERIVED_TYPE_A) , POINTER :: P_ARR_INT
TYPE( DERIVED_TYPE_A ) , DIMENSION( 3 ) , TARGET :: ARR_INT

D00: DO I = 1 , 3

        P_ARR_INT => ARR_INT( I )

        CALL P_ARR_INT%CALC_I_00( I )

        WRITE( * , * ) ARR_INT( I )%TAKE_I_00()

     END DO D00

END PROGRAM TYPE_SUBMODULES

有没有办法在子模块中使用派生类型（带有组件和过程）？例如，这样：

SUBMODULE( PARENT_MODULE ) TYPE_A

  TYPE :: D_TYPE_A

    INTEGER :: I_00

    CONTAINS

  !  PROCEDURE :: CALC_I_00 => CALC_DATA_I_00
  !  PROCEDURE :: TAKE_I_00 => TAKE_DATA_I_00

  END TYPE D_TYPE_A

  CLASS( D_TYPE_A ) , POINTER :: P_ARR_INT
  TYPE( DERIVED_TYPE_A ) , DIMENSION( 3 ) , TARGET :: ARR_INT

CONTAINS

!MODULE SUBROUTINE CALC_DATA_I_00( THIS )
!
!    CLASS( D_TYPE_A ) :: THIS
!   ! INTEGER , INTENT( IN ) :: NUM_00
!
!    THIS%I_00 = NUM_00 + 1
!
!END SUBROUTINE CALC_DATA_I_00
!
!!FUNCTION TAKE_DATA_I_00( THIS ) RESULT( RES_00 )
!!
!!    CLASS( D_TYPE_A ) :: THIS
!!    INTEGER :: RES_00
!!
!!    RES_00 = THIS%I_00
!!
!!END FUNCTION TAKE_DATA_I_00

END SUBMODULE TYPE_A

在这种情况下，我不能在主程序中使用指针和目标变量，我想这样做，或者是否可以在中声明指针和目标变量PARENT_MODULE.

我的 IDE 是带有 Gfortran 编译器的 Code::Blocks 17.12。编译器版本为：MinGW 6.3.0。

有没有办法在子模块中使用派生类型（带有组件和过程）？

简短回答：no。 （至少不是你所期望的那样）

子模块是添加到语言中的一项功能，用于解决一个特定问题：接口和实现的分离。主要动机是当您只需要更改模块中的实现细节时生成的编译级联。

但子模块不是模块！

子模块与模块绑定，并为该模块中声明的过程提供实现。因此，子模块可以访问其父模块中的所有声明。尽管如此，该模块对其子模块一无所知，并且不会像模块一样使用其子模块。该模块只是希望您在链接时添加子模块，足以覆盖所有缺少的过程实现。

因此，如果您要在子模块中声明类型或其他任何内容，那么它对于父模块来说将是本地的且不透明的。

如果您需要通过另一个单元中的主机访问程序单元的声明，则需要模块。

您必须明智地设计您的解决方案。按主题和依赖项分隔模块。如果三种类型相互引用，那么它们非常相关，应该位于同一程序单元中。