虽然您的代码似乎只有一个问题 - 如何用任务填充记录中的整数字段 - 当您解决这个问题时，您将遇到另一个问题 - 从多个线程读取和写入相同的内存位置。
1. 如何填充记录中的整数字段？
记录是值类型，动态数组是引用类型。这就是为什么您的代码可以更新数组中的值但无法更新记录中的值的原因。
让我们看看这里发生了什么。
function CreateTask(first, last: integer; var pmyrec: myrec): ITask;
var
mylocalrec: myrec;
begin
mylocalrec := pmyrec;
Since mylocalrec and pmyrec是记录（值类型），它们的内容将占用两个不同的内存位置。以上作业将复制content of the pmyrec into mylocalrec.
这将相当于以下内容：
mylocalrec.vet := pmyrec.vet;
mylocalrec.total := pmyrec.total;
mylocalrec.average := pmyrec.average;
Since total and average也是值类型，它们的内容将被复制，从此时起，对这些整数字段中的任何一个进行任何更改mylocalrec不会对原来有任何影响pmyrec。这就是您的代码失败的原因。
为什么分配动态数组字段vet from pmyrec to mylocalrec works?
因为动态数组是引用类型 - 从一个变量到另一个变量的赋值仅复制引用（指针）的值，而不是实际内容。两个都vet变量将指向您开始运行任务之前分配的同一数组。
要解决上述问题，您必须传递一些引用类型而不是值类型。最简单的事情是声明记录指针类型并传递该类型。
type
myrec = record
vet: array of integer;
total: integer;
average: integer;
end;
pmyrec = ^myrec;
function CreateTask(first, last: integer; rec: pmyrec): ITask;
var
mylocalrec: pmyrec;
begin
mylocalrec := rec;
Result := TTask.Create(
procedure
begin
ProcA(first, last, mylocalrec^)
end);
end;
...
Ptasks[indtask] := CreateTask(vfirst, vlast, @Recarray);
2. 如何解决线程问题？
解决原始问题后，您将遇到线程问题。从多个线程读取和写入同一内存位置是不安全的。您得到的结果可能不正确。虽然您可以运行代码数千次并且所有值可能都是正确的，但迟早您会遇到它们不正确的情况。
在您的情况下，填充动态数组是安全的，因为每个线程都在数组的不同部分上操作，并且在任务运行时不会重新分配数组（其大小不会更改）。这部分代码是线程安全的。
计算total and average不是线程安全的。
您必须将此类代码与主线程同步 - 在这种情况下，所有读取和写入都将从主线程完成，您将获得正确的结果。或者您必须在所有任务完成后运行此类代码。哪个更适合特定情况。
procedure ProcA(const pin, pfin: integer; prec: pmyrec);
var
vind: integer;
total: integer;
begin
total := 0;
for vind := pin to pfin do
begin
prec.vet[vind] := vind * 10;
total := total + prec.vet[vind]; // sum all array values
end;
TThread.Synchronize(nil,
procedure
begin
prec.total := prec.total + total;
prec.average := Trunc(prec.total / Length(prec.vet)); // calculates the average
end);
end;
然而，与任务内的主线程同步会导致死锁TTask.WaitForAll在您的情况下，该方法也从主线程运行。要解决该部分，您还必须运行整个Test来自另一个线程的方法。
TTask.Run(
procedure
begin
Test;
end);
当我们将所有这些部分放在一起时，完整的代码将是：
program ProjectTest;
{$APPTYPE CONSOLE}
{$R *.res}
uses
System.SysUtils,
System.Classes,
System.Threading;
type
myrec = record
vet: array of integer;
total: integer;
average: integer;
end;
pmyrec = ^myrec;
// (1) ===> here is the major procedure that populates the dyn. array and
// calculates other two fields : myrec.total and myrec.avg
procedure ProcA(const pin, pfin: integer; prec: pmyrec);
var
vind: integer;
total: integer;
begin
total := 0;
for vind := pin to pfin do
begin
prec.vet[vind] := vind * 10;
total := total + prec.vet[vind]; // sum all array values
end;
TThread.Synchronize(nil,
procedure
begin
prec.total := prec.total + total;
prec.average := Trunc(prec.total / Length(prec.vet)); // calculates the average
end);
end;
// (2) Here iTask is created and calls ProcA
function CreateTask(first, last: integer; rec: pmyrec): ITask;
var
mylocalrec: pmyrec;
begin
mylocalrec := rec;
Result := TTask.Create(
procedure
begin
ProcA(first, last, mylocalrec);
end);
end;
procedure Test;
var
Recarray: myrec;
Ptasks: array of ITask;
vind, indtask, vslice: integer;
vfirst, vlast, vthreads, vsize: integer;
begin
vthreads := 4;
vsize := 16;
SetLength(Ptasks, vthreads);
SetLength(Recarray.vet, vsize);
// Initialize the array , just to check after iTask execution
for vind := low(Recarray.vet) to high(Recarray.vet) do
Recarray.vet[vind] := -33;
// initialize the sum and average field just to check after iTask execution
Recarray.total := -1;
Recarray.average := -2;
// portion of array to scan for each iTask
vslice := Length(Recarray.vet) div vthreads;
for indtask := low(Ptasks) to high(Ptasks) do
begin
vfirst := indtask * vslice;
vlast := (indtask + 1) * vslice - 1;
if (Length(Recarray.vet) mod vthreads <> 0) and (indtask = high(Ptasks)) then vlast := high(Recarray.vet);
Ptasks[indtask] := CreateTask(vfirst, vlast, @Recarray);
end;
// Starting all Tasks
for indtask := low(Ptasks) to high(Ptasks) do
Ptasks[indtask].Start;
// Waits for all Tasks been concluded
TTask.WaitForAll(Ptasks);
// (3) Here it is listed the array contents and it is ok
for vind := low(Recarray.vet) to high(Recarray.vet) do
Writeln(' Array position : ' + Format('%.3d', [vind]) + ' content : ' + Recarray.vet[vind].tostring);
Writeln(' =========================================================');
// (4) Here is is listed fields recarray.total and recarray.avg and they were not
// processed inside the iTask . I expected to see the computed values for those fields
Writeln(' Array sum : ' + Format('%.0d', [Recarray.total]) + ' Array average : ' + Format('%5.2n', [Recarray.average * 1.0]));
end;
begin
TTask.Run(
procedure
begin
Test;
end);
end.
