Fortran 是否通过函数和子例程调用保留内部变量的值？

经过多次痛苦的调试后，我相信我已经找到了 Fortran 的一个独特属性，我想在 stackoverflow 上验证它。

我注意到的是，至少内部逻辑变量的值在函数或子例程调用中得以保留。

这是一些示例代码来说明我的观点：

PROGRAM function_variable_preserve
IMPLICIT NONE

CHARACTER(len=8) :: func_negative_or_not ! Declares function name
INTEGER :: input
CHARACTER(len=8) :: output

input = -9

output = func_negative_or_not(input)
WRITE(*,10) input, " is ", output
10 FORMAT("FUNCTION: ", I2, 2A)

CALL sub_negative_or_not(input, output)
WRITE(*,20) input, " is ", output
20 FORMAT("SUBROUTINE: ", I2, 2A)

WRITE(*,*) 'Expected negative.'


input = 7
output = func_negative_or_not(output)
WRITE(*,10) input, " is ", output

CALL sub_negative_or_not(input, output)
WRITE(*,20) input, " is ", output

WRITE(*,*) 'Expected positive.'

END PROGRAM function_variable_preserve

CHARACTER(len=*) FUNCTION func_negative_or_not(input)
IMPLICIT NONE

INTEGER, INTENT(IN) :: input
LOGICAL :: negative = .FALSE.

IF (input < 0) THEN
    negative = .TRUE.
END IF

IF (negative) THEN
    func_negative_or_not = 'negative'
ELSE 
    func_negative_or_not = 'positive'
END IF

END FUNCTION func_negative_or_not

SUBROUTINE sub_negative_or_not(input, output)
IMPLICIT NONE

INTEGER, INTENT(IN) :: input
CHARACTER(len=*), INTENT(OUT) :: output
LOGICAL :: negative = .FALSE.

IF (input < 0) THEN
    negative = .TRUE.
END IF

IF (negative) THEN
    output = 'negative'
ELSE 
    output = 'positive'
END IF

END SUBROUTINE sub_negative_or_not

这是输出：

FUNCTION: -9 is negative
SUBROUTINE: -9 is negative
 Expected negative.
FUNCTION:  7 is negative
SUBROUTINE:  7 is negative
 Expected positive.

正如您所看到的，似乎一旦函数或子例程被调用一次，逻辑变量negative，如果切换到.TRUE.，尽管初始化了，但仍然如此negative to .FALSE.在类型声明语句中。

当然，我可以通过添加一行来纠正这个问题 负数 = .FALSE。 在我的函数和子例程中声明变量之后。

然而，这对我来说似乎很奇怪，这是必要的。

为了可移植性和代码可重用性，语言（或编译器可能）不应该要求每次调用子例程或函数时重新初始化所有内部变量吗？

回答你的问题：是的 Fortran 确实通过函数和子例程调用保留内部变量的值.

在某些条件下...

如果您使用 SAVE 属性声明一个内部变量，则它的值将从一次调用保存到下一次调用。当然，这在某些情况下很有用。

然而，您的问题是第一次了解 Fortran 陷阱之一时的常见反应：如果您在其声明中初始化内部变量，那么它会自动获取 SAVE 属性。您已经在子例程中完全做到了这一点。这是符合标准的。如果您不希望发生这种情况，请不要在声明中进行初始化。

这是（一些）该语言的新手感到惊讶和抱怨的原因。但无论他们多么抱怨，它都不会改变，所以你只需要 (a) 了解它并 (b) 在意识到它的情况下进行编程。