wmic 命令的批处理脚本中的文本乱码

我正在尝试运行批处理脚本来获取基本的计算机信息，如 CPU、RAM 和活动网卡。这是我的代码

@Echo OFF

set newline=^& echo.

echo Manufacturer Information> test1.txt

systeminfo|findstr /c:"Host Name" /c:"OS Name" /c:"System Model:" /c:"System Type:" /c:"Total Physical Memory:" >>test1.txt

echo CPU Information:>> test1.txt

wmic cpu get Name /Format:list >> test1.txt

echo %newline%Process Information:>> test1.txt

wmic computersystem get NumberofProcessors /Format:list >> test1.txt

echo %newline%NIC Information:>> test1.txt

wmic nicconfig where "IPEnabled=TRUE" get ipaddress, macaddress,defaultipgateway /format:list >>test1.txt

输出看起来：

制造商信息 主机名：DK-IT 操作系统名称：
Microsoft Windows 8.1 单语言系统模型：
Inspiron 灵越 7537 系统类型：基于 x64 的 PC 总物理性能 内存：6,043 MB CPU 信息：

 N a m e = I n t e l ( R )   C o r e ( T M )   i 5 - 4 2 0 0 U   C P U   @   1 . 6 0 G H z 



Process Information:


 N u m b e r O f P r o c e s s o r s = 1 



NIC Information:


 D e f a u l t I P G a t e w a y = { " 1 0 . 5 . 1 . 1 " }     I P A d d r e s s = { " 1 0 . 5 . 4 . 5 4 " , " f e 8 0 : : 1 0 e b : 1 d

2 d : 2 0 8 8 : 8 b a 1 " } MAC 地址 s = 0 C : 8 B : F D : 9 C : 8 0 : 4 7

 D e f a u l t I P G a t e w a y =     I P A d d r e s s = { " 1 9 2 . 1 6 8 . 1 9 9 . 1 " }     M A C A d d r e s s = 0 0 : 5 0 : 5 6 :

C 0 : 0 0 : 0 1

默认 IP 网关 = IPA 地址 = { " 1 9 2 。 1 6 8 。 1 9 0 。 1 " , " f e 8 0 : : 6 4 b 2 : 2 a a a : e f 6 4 : f a 9 a "} MAC 地址 = 0 0 : 5 0 : 5 6 : C 0 : 0 0 : 0 8

有人可以帮忙修改批处理文件输出的视图吗？

您的问题是 SYSTEMINFO 产生 ANSII 输出（与大多数命令一样），但 WMIC 产生 Unicode 输出。两者混合得不好。

以下是全部产生 ANSII 输出的三种解决方案。

1) 将 WMIC 输出传送到 MORE

MORE 将 Unicode 转换为 ANSII。我还将该结果通过管道传递给 FINDSTR 以消除空白行。此解决方案的唯一问题是转换的怪癖会导致 WMIC 输出在每行末尾有一个额外的回车符 (<CR><CR><LF>代替<CR><LF>)

@echo OFF
>test1.txt (
  echo Manufacturer Information:
  systeminfo|findstr /c:"Host Name" /c:"OS Name" /c:"System Model:" /c:"System Type:" /c:"Total Physical Memory:"

  echo(
  echo CPU Information:
  wmic cpu get Name /Format:list | more | findstr .
  wmic computersystem get NumberofProcessors /Format:list | more | findstr .

  echo(
  echo NIC Information:
  wmic nicconfig where IPEnabled=TRUE get ipaddress, macaddress,defaultipgateway /format:list | more | findstr .
)

------------------------------------------

剩下的解决方案都格式正确，没有任何额外的<CR>

2) 将 WMIC 输出写入临时文件，后跟 TYPE

临时文件采用 Unicode 格式，并且 TYPE 可以正确地将 Unicode 转换为 ASCII。我仍然将结果通过管道传输到 FINDSTR 以消除空白行。

@echo OFF
>test2.txt (
  echo Manufacturer Information:
  systeminfo|findstr /c:"Host Name" /c:"OS Name" /c:"System Model:" /c:"System Type:" /c:"Total Physical Memory:"

  echo(
  echo CPU Information:
  call :wmic cpu get Name /Format:list
  call :wmic computersystem get NumberofProcessors /Format:list

  echo(
  echo NIC Information:
  call :wmic nicconfig where IPEnabled=TRUE get ipaddress, macaddress,defaultipgateway /format:list
)
exit /b

:wmic
wmic %* >test.tmp
type test.tmp | findstr .
del test.tmp
exit /b

3) 通过两个 FOR /F 循环运行 WMIC。

第一个 FOR /F 将 WMIC 输出转换为 ANSII，但它有额外的<CR>在每行的末尾。第二个 FOR /F 去掉不需要的尾随<CR>。 FOR /F 自动去除空行。

@echo OFF
>test3.txt (
  echo Manufacturer Information:
  systeminfo|findstr /c:"Host Name" /c:"OS Name" /c:"System Model:" /c:"System Type:" /c:"Total Physical Memory:"

  echo(
  echo CPU Information:
  call :wmic cpu get Name /Format:list
  call :wmic computersystem get NumberofProcessors /Format:list

  echo(
  echo NIC Information:
  call :wmic nicconfig where IPEnabled=TRUE get ipaddress, macaddress,defaultipgateway /format:list
)
exit /b

:wmic
for /f "delims=" %%A in ('"wmic %*"') do for /f "delims=" %%B in ("%%A") do echo %%B
exit /b