我有一个脚本可以查找特定已安装的软件，但我在获取该软件的版本时也遇到了麻烦。例如，假设我正在获取所有已安装的 Microsoft 软件的列表。到目前为止，这是我所拥有的：
echo software installed > software_list.txt
echo ================= >>software_list.txt
reg export HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall temp1.txt
find "Microsoft" temp1.txt| find "DisplayName" > temp2.txt
for /f "tokens=2,3 delims==" %%a in (temp2.txt) do (echo %%a >> software_list.txt)
start notepad "software_list.txt"
del temp1.txt temp2.txt
如何从 reg 导出中获取 DisplayVersion？如果我用 DisplayVersion 替换 DisplayName，则什么也找不到。或者，我应该采取其他途径吗？
更换DisplayName with DisplayVersion由于该行的工作方式，导致输出为空：
find "Microsoft" temp1.txt| find "DisplayName" > temp2.txt
该行的作用是查找中的所有行temp2.txt文件同时包含微软 and 显示名称子字符串（即，它查找名称包含的产品微软）。线路与显示版本依次包含产品版本号且不包含单词微软，这就是为什么你得到空输出的原因。
我可以建议一些使用的替代解决方案WMI:
-
解析HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall使用脚本（VBScript、PowerShell 等）而不是批处理文件创建子项，因为脚本语言为文本操作提供了更好的支持。下面是一个 VBScript 示例，它输出已安装的 Microsoft 产品的名称和版本（名称包含微软，更准确地说）：
On Error Resume Next
Const strComputer = "."
Const HKLM = &H80000002
Const strKeyPath = "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall"
Dim oReg, arrSubKeys, strProduct, strDisplayName, strVersion
Set oReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & _
strComputer & "\root\default:StdRegProv")
' Enumerate the subkeys of the Uninstall key
oReg.EnumKey HKLM, strKeyPath, arrSubKeys
For Each strProduct In arrSubKeys
' Get the product's display name
oReg.GetStringValue HKLM, strKeyPath & "\" & strProduct, "DisplayName", strDisplayName
' Process only products whose name contain 'Microsoft'
If InStr(1, strDisplayName, "Microsoft", vbTextCompare) > 0 Then
' Get the product's display version
oReg.GetStringValue HKLM, strKeyPath & "\" & strProduct, "DisplayVersion", strVersion
WScript.Echo strDisplayName & vbTab & strVersion
End If
Next
Usage:
cscript //nologo productlist.vbs
cscript //nologo productlist.vbs > productlist.txt
-
如果您感兴趣的软件是由Windows安装程序，您可以通过查询 WMI 来获取有关该软件的信息（例如名称、供应商、版本等）Win32_Product班级。这wmic实用程序允许您直接从命令行和批处理文件执行此操作。以下是一些示例：
-
打印已安装软件的名称和版本：
wmic product get Name, Version
-
列出所有已安装的 Microsoft 产品：
wmic product where "Vendor like '%Microsoft%'" get Name, Version
-
列出已安装的产品Office以他们的名字：
wmic product where "Name like '%Office%'" get Name, Version
为了保存wmic输出到文件，您可以使用/output和（可选）/format参数，例如：
wmic /output:software.txt product get Name, Version
wmic /output:software.htm product get Name, Version /format:htable
欲了解更多信息wmic语法，参见wmic /?
本文内容由网友自发贡献，版权归原作者所有，本站不承担相应法律责任。如您发现有涉嫌抄袭侵权的内容，请联系:hwhale#tublm.com(使用前将#替换为@)
