DataGridView WinForms 自动重新加载/更新/刷新

我有一个带有DataGridView控制。

我将其绑定到附加的数据库文件 (.mdf) 中。

我通过生成动态 Insert 语句来执行插入。然后我将此 sql 语句泵入SqlCommand对象并执行ExecuteNonQuery()方法。所有这些都是通过处理Button单击事件。该按钮和 gridview 位于同一窗体上。

Public Sub InsertRow(ByVal param1 As String, ByVal param2 As String, ByVal param3 As String)

    Dim strConn As String = (the connection string)
    Dim sqlConn As New SqlConnection(strConn)

    Dim insertSQL As String = "INSERT INTO theTable VALUES ('" + param1 + "', '" + param2 + "', '" + param3 + "', '" + DateTime.Now + "', '" + DateTime.Now + "')"
    Dim comm As New SqlCommand(insertSQL, sqlConn)
    sqlConn.Open()
    comm.ExecuteNonQuery()
    sqlConn.Close()
End Sub

Private Sub btnInsert_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnInsert.Click

    InsertRow("a","b","c")

End Sub

代码执行后，DataGridView没有更新（保持不变）。我必须退出表单并重新加载它才能更新网格视图。

由于某些原因，我无法使用DataTable目的。 但我希望每次运行插入时都更新此网格视图。

有人可以告诉我该怎么做吗？ 谢谢

P.S 虽然我是在 VB 中执行此操作，但我不介意在 C# 中收到答案

首先，你必须使用SQLCommand and Parameters避免 sql 注入，因为您正在使用SQLClient命名空间。尝试将此作为您的Insert程序。

Private Sub InsertSQL(ByVal param1 As String, ByVal param2 As String, ByVal param3 As String)

    Using sqlConn As New SqlConnection("ConnectionStringHere")
        Using sqlComm As New SqlCommand()
            sqlComm.Connection = sqlConn
            sqlComm.CommandType = CommandType.Text
            sqlComm.CommandText = "INSERT INTO theTable VALUES (@Param1,@Param2,@Param3,@Param4,@Param5)"
            With sqlComm.Parameters
                .AddWithValue("@Param1", param1)
                .AddWithValue("@Param2", param2)
                .AddWithValue("@Param3", param3)
                .AddWithValue("@Param4", Now)
                .AddWithValue("@Param5", Now)
            End With

            Try
                sqlConn.Open()
                sqlComm.ExecuteNonQuery()
            Catch ex As SqlException
                MsgBox(ex.Message.ToString, MsgBoxStyle.Exclamation, "Error No. " & ex.ErrorCode.ToString)
            Finally
                sqlConn.Close()
            End Try

        End Using
    End Using

End Sub

其次，你为什么不喜欢使用DataTable来绑定你的DataGridView？嗯，这是另一个解决方案。这是你使用的SQLDataReader你必须循环它才能将记录放入网格中。

Private Sub ReloadGrid(ByVal connectionString As String)
    Dim queryString As String = "Your Query Here"

    Using connection As New SqlConnection(connectionString)
        Dim command As New SqlCommand(queryString, connection)
        connection.Open()

        Dim reader As SqlDataReader = command.ExecuteReader()

        DataGridView1.Rows.Clear() ' Clear All Rows '

        While reader.Read()
           ' Console.WriteLine(String.Format("{0}, {1}",  reader(0), reader(1))) '
           ' Insert the record in your datagrid '
           Dim row As String() = New String() {reader(0).ToString, reader(1).ToString, reader(2).ToString}
           DataGridView1.Rows.Add(row)
        End While

        ' Call Close when done reading. '
        reader.Close()
    End Using
End Sub