考虑使用MSXML,一个符合 W3C 的 XML API 综合库,您可以使用它通过 DOM 方法构建 XML(createElement
, appendChild
, setAttribute
) 而不是连接文本字符串。 XML 不完全是文本文件,而是具有编码和树结构的标记文件。 Excel 通过引用或后期绑定配备了 MSXML COM 对象,并且可以从 Excel 数据迭代构建树,如下所示。
下面有 300 行 x 12 列的随机日期,甚至不需要一分钟(实际上是单击宏后几秒钟),它甚至使用嵌入式 XSLT 样式表漂亮地打印带有换行符和缩进的原始输出(如果您不漂亮地打印, MSXML 将文档输出为一长的连续行)。
Input
![Name Date Spreadsheet](https://i.stack.imgur.com/VrUZ3.png)
VBA (当然与实际数据一致)
Sub xmlExport()
On Error GoTo ErrHandle
' VBA REFERENCE MSXML, v6.0 '
Dim doc As New MSXML2.DOMDocument60, xslDoc As New MSXML2.DOMDocument60, newDoc As New MSXML2.DOMDocument60
Dim root As IXMLDOMElement, dataNode As IXMLDOMElement, datesNode As IXMLDOMElement, namesNode As IXMLDOMElement
Dim i As Long, j As Long
Dim tmpValue As Variant
' DECLARE XML DOC OBJECT '
Set root = doc.createElement("DataSet")
doc.appendChild root
' ITERATE THROUGH ROWS '
For i = 2 To Sheets(1).UsedRange.Rows.Count
' DATA ROW NODE '
Set dataNode = doc.createElement("DataRow")
root.appendChild dataNode
' DATES NODE '
Set datesNode = doc.createElement("Dates")
datesNode.Text = Sheets(1).Range("A" & i)
dataNode.appendChild datesNode
' NAMES NODE '
For j = 1 To 12
tmpValue = Sheets(1).Cells(i, j + 1)
If IsDate(tmpValue) And Not IsNumeric(tmpValue) Then
Set namesNode = doc.createElement("Name" & j)
namesNode.Text = Format(tmpValue, "yyyy-mm-dd")
dataNode.appendChild namesNode
End If
Next j
Next i
' PRETTY PRINT RAW OUTPUT '
xslDoc.LoadXML "<?xml version=" & Chr(34) & "1.0" & Chr(34) & "?>" _
& "<xsl:stylesheet version=" & Chr(34) & "1.0" & Chr(34) _
& " xmlns:xsl=" & Chr(34) & "http://www.w3.org/1999/XSL/Transform" & Chr(34) & ">" _
& "<xsl:strip-space elements=" & Chr(34) & "*" & Chr(34) & " />" _
& "<xsl:output method=" & Chr(34) & "xml" & Chr(34) & " indent=" & Chr(34) & "yes" & Chr(34) & "" _
& " encoding=" & Chr(34) & "UTF-8" & Chr(34) & "/>" _
& " <xsl:template match=" & Chr(34) & "node() | @*" & Chr(34) & ">" _
& " <xsl:copy>" _
& " <xsl:apply-templates select=" & Chr(34) & "node() | @*" & Chr(34) & " />" _
& " </xsl:copy>" _
& " </xsl:template>" _
& "</xsl:stylesheet>"
xslDoc.async = False
doc.transformNodeToObject xslDoc, newDoc
newDoc.Save ActiveWorkbook.Path & "\Output.xml"
MsgBox "Successfully exported Excel data to XML!", vbInformation
Exit Sub
ErrHandle:
MsgBox Err.Number & " - " & Err.Description, vbCritical
Exit Sub
End Sub
Output
<?xml version="1.0" encoding="UTF-8"?>
<DataSet>
<DataRow>
<Dates>Date1</Dates>
<Name1>2016-04-23</Name1>
<Name2>2016-09-22</Name2>
<Name3>2016-09-23</Name3>
<Name4>2016-09-24</Name4>
<Name5>2016-10-31</Name5>
<Name6>2016-09-26</Name6>
<Name7>2016-09-27</Name7>
<Name8>2016-09-28</Name8>
<Name9>2016-09-29</Name9>
<Name10>2016-09-30</Name10>
<Name11>2016-10-01</Name11>
<Name12>2016-10-02</Name12>
</DataRow>
<DataRow>
<Dates>Date2</Dates>
<Name1>2016-06-27</Name1>
<Name2>2016-08-14</Name2>
<Name3>2016-07-08</Name3>
<Name4>2016-08-22</Name4>
<Name5>2016-11-03</Name5>
<Name6>2016-07-28</Name6>
<Name7>2016-08-23</Name7>
<Name8>2016-11-01</Name8>
<Name9>2016-11-01</Name9>
<Name10>2016-08-11</Name10>
<Name11>2016-08-18</Name11>
<Name12>2016-09-23</Name12>
</DataRow>
...