声明：(XSLT)"isn't suitable for transforming from structured text to XML. "和声明"XSLTmusthave XML as the input document"**都是错误的.
我正在考虑两种方法
定义一个业务实体并通过在输入文本上使用子字符串函数填充实体属性，然后将该实体序列化为
XML
预定义 xml 结构，使用 xslt 导航到每个节点并通过在输入文本上使用子字符串函数来填充值。
事实上，方法 2 使用 XSLT 很容易实现:
一、XSLT 1.0:
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:template match="/*/text()" name="processLines">
<xsl:param name="pText" select="."/>
<xsl:if test="contains($pText, '
')">
<xsl:variable name="vLine" select=
"substring-before($pText, '
')"/>
<user>
<name>
<xsl:value-of select=
"translate(substring-before($vLine, ' '),'_',' ')"/>
</name>
<city>
<xsl:value-of select=
"translate(substring-before(substring-after($vLine, ' '),' '),
'_',
' '
)
"/>
</city>
<zipCode>
<xsl:value-of select=
"translate(substring-after(substring-after($vLine, ' '),' '),
'_',
' '
)
"/>
</zipCode>
</user>
<xsl:call-template name="processLines">
<xsl:with-param name="pText" select=
"substring-after($pText, '
')"/>
</xsl:call-template>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
当此转换应用于特殊格式的文本时（包装在单个顶部元素中以使其格式良好 - 正如我们将在 XSLT 2.0 中看到的那样，这种包装是不必要的）：
<t>Testuser new_york 10018
usera seattle 98000
userb bellevue 98004
userb redmond 98052
</t>
产生了想要的结果:
<user>
<name>Testuser</name>
<city>new york</city>
<zipCode>10018</zipCode>
</user>
<user>
<name>usera</name>
<city>seattle</city>
<zipCode>98000</zipCode>
</user>
<user>
<name>userb</name>
<city>bellevue</city>
<zipCode>98004</zipCode>
</user>
<user>
<name>userb</name>
<city>redmond</city>
<zipCode>98052</zipCode>
</user>
Notes:
这只是一个演示如何完成任务的演示。这就是为什么我不处理固定宽度字段（虽然会更容易），而是处理空格分隔的值。
任何值中包含的任何空格都作为下划线（或我们选择的任何字符，我们知道它们永远不会成为任何值的一部分）输入到输入中。在输出时，任何下划线都会转换为真实的空格。
二. XSLT 2.0 解决方案:
<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:variable name="vText" select=
"unparsed-text('file:///c:/temp/delete/delete.txt')"/>
<xsl:variable name="vLines" select=
"tokenize($vText, '
?
')[normalize-space()]"/>
<xsl:template match="/">
<xsl:for-each select="$vLines">
<xsl:variable name="vFields" select=
"tokenize(., ' ')[normalize-space()]"/>
<user>
<name>
<xsl:sequence select="translate($vFields[1], '_',' ')"/>
</name>
<city>
<xsl:sequence select="translate($vFields[2], '_',' ')"/>
</city>
<zipCode>
<xsl:sequence select="translate($vFields[3], '_',' ')"/>
</zipCode>
</user>
</xsl:for-each>
</xsl:template>
</xsl:stylesheet>
当此转换应用于任何 XML 文档时（未使用且实际上不需要，因为在 XSLT 2.0 中不需要源 XML 文档），并且如果文件C:\temp\delete\delete.txt is:
Testuser new_york 10018
usera seattle 98000
userb bellevue 98004
userb redmond 98052
再次产生想要的正确结果:
<user>
<name>Testuser</name>
<city>new york</city>
<zipCode>10018</zipCode>
</user>
<user>
<name>usera</name>
<city>seattle</city>
<zipCode>98000</zipCode>
</user>
<user>
<name>userb</name>
<city>bellevue</city>
<zipCode>98004</zipCode>
</user>
<user>
<name>userb</name>
<city>redmond</city>
<zipCode>98052</zipCode>
</user>
Notes:
使用标准 XSLT 2.0 函数unparsed-text().
使用标准 XPath 2.0 函数tokenize().
最后说明:
最复杂的文本处理完全以 XSLT 的工业方式完成。FXSL 库包含一个通用的LR(1) 解析器 and a 调整 YACC 以生成 XML 格式的表这是这个通用运行时 LR(1) 解析器的输入。
使用这个工具我成功了内置解析器对于 JSON 和 XPath 2.0 等复杂语言。
