CreateProcess 立即返回，但前提是启动的进程被隐藏

我有下面的 Delphi 代码来为 CreateProcess API 调用提供一个友好的包装器。

function StartProcess(ExeName: string; CmdLineArgs: string = '';
  ShowWindow: boolean = True; WaitForFinish: boolean = False): integer;
const
  c_Wait = 100;
var
  StartInfo: TStartupInfo;
  ProcInfo: TProcessInformation;
begin
  //Simple wrapper for the CreateProcess command
  //returns the process id of the started process.
  FillChar(StartInfo,SizeOf(TStartupInfo),#0);
  FillChar(ProcInfo,SizeOf(TProcessInformation),#0);
  StartInfo.cb := SizeOf(TStartupInfo);

  //this block is the only part of execution that is different
  //between my two calls.  What am I doing wrong with these flags?
  if not(ShowWindow) then begin
    StartInfo.dwFlags := STARTF_USESHOWWINDOW or STARTF_USESTDHANDLES;
    StartInfo.wShowWindow := SW_HIDE;
  end;

  CreateProcess(nil,PChar(ExeName + ' ' + CmdLineArgs),nil,nil,False,
    CREATE_NEW_PROCESS_GROUP + NORMAL_PRIORITY_CLASS,nil,nil,StartInfo,
    ProcInfo);

  Result := ProcInfo.dwProcessId;

  if WaitForFinish then begin
    while IsProcessRunning(Result) do begin
      Sleep(c_Wait);
    end;
  end;

end;

我正在使用它来启动批处理文件，并等待批处理文件返回。 只要我将“ShowWindow”值保留为 True，它就可以很好地工作。如果我尝试隐藏命令行窗口，它会立即返回，不会出现错误。谁能帮助我理解我的错误？下面是示例用法和注释。

//this will not show the cmd line window, and it will return immediately
StartProcess('C:\run_me.bat','',False,True);

//this will show the cmd line, and (correctly) wait for the job to finish
StartProcess('C:\run_me.bat','',True,True);

奇怪的是，当窗口隐藏时，我仍然得到一个进程 ID，就像它已启动一样。但它退出得太快了，我在任务管理器中看不到它。

如果我将批处理文件更改为在其末尾有一个“暂停”（因此它永远不会真正完成），我仍然会得到相同的结果。因此，当我在代码的“if not(ShowWindow)”块中设置标志时，该进程实际上并未启动。

根据 Rob Kennedy 的建议，我的代码如下所示：

function StartProcess(ExeName: string; CmdLineArgs: string = '';
  ShowWindow: boolean = True; WaitForFinish: boolean = False): integer;
var
  StartInfo: TStartupInfo;
  ProcInfo: TProcessInformation;
begin
  //Simple wrapper for the CreateProcess command
  //returns the process id of the started process.
  FillChar(StartInfo,SizeOf(TStartupInfo),#0);
  FillChar(ProcInfo,SizeOf(TProcessInformation),#0);
  StartInfo.cb := SizeOf(TStartupInfo);

  if not(ShowWindow) then begin
    StartInfo.dwFlags := STARTF_USESHOWWINDOW;
    StartInfo.wShowWindow := SW_HIDE;
  end;

  CreateProcess(nil,PChar(ExeName + ' ' + CmdLineArgs),nil,nil,False,
    CREATE_NEW_PROCESS_GROUP + NORMAL_PRIORITY_CLASS,nil,nil,StartInfo,
    ProcInfo);

  Result := ProcInfo.dwProcessId;

  if WaitForFinish then begin
    WaitForSingleObject(ProcInfo.hProcess,Infinite);
  end;

  //close process & thread handles
  CloseHandle(ProcInfo.hProcess);
  CloseHandle(ProcInfo.hThread);
end;

当你设置ShowWindow = False，您设置启动标志以包括StartF_UseStdHandles，但您永远不会为标准 I/O 句柄提供任何值。当新进程尝试写入任何输出时，它将失败，因为它没有有效的输出句柄。

如果您不打算为句柄提供值，那么就不要告诉CreateProcess句柄字段中具有有效值。从启动标志中省略该标志。

创建流程时不会出现任何错误，因为creating过程很顺利。这只是after该进程开始运行时遇到了问题。您没有检查进程的退出代码，因此您无法检测到任何故障。