如何使用 Power BI DAX 从移动表计算每天的库存？

我有一张库存变动表。每个库存项目都有一个唯一的 ID，并且它们会随着时间的推移更改状态（假设状态 A、B、C 和 D，但并不总是按此顺序）。 ID的每次状态变化都是表中的一条新记录，并带有状态变化的时间戳。我的目标是使用 Power BI DAX 计算某一天状态“B”的库存数量。其逻辑是计算在某一天之前违反状态“B”但在该天之前没有任何更新状态的不同 ID 的数量。

源表示例：

ID  |  TimeStamp  |  Status
1   |  8/20/2018  |    A
1   |  8/21/2018  |    B
1   |  8/24/2018  |    C
2   |  8/19/2018  |    A
2   |  8/20/2018  |    B
2   |  8/22/2018  |    C
2   |  8/24/2018  |    D
3   |  8/18/2018  |    A
3   |  8/21/2018  |    B
4   |  8/15/2018  |    A
4   |  8/17/2018  |    B
4   |  8/24/2018  |    D

输出表示例：

Date       |  Count of Items in Status B on this Day
8/17/2018  |     3
8/18/2018  |     2
8/19/2018  |     0
8/20/2018  |     8
8/21/2018  |     10
8/22/2018  |     5
8/23/2018  |     3

我正在考虑为每个 ID 的状态为“B”的最新时间戳创建一个表，然后在状态“B”的时间戳之后查找下一个时间戳（如果适用）：

ID (primary key)  |  TimeStamp of 'B' breached | TimeStamp of next status breach
1                 |     8/20/2018              |  8/21/2018
2                 |     8/18/2018              |  8/22/2018
3                 |     8/21/2018              |  
4                 |     8/15/2018              |  8/20/2018

然后，我将上述数据插入到日期上下文中，并计算上表中 ID 的数量，其中““B”的时间戳被破坏“值较小并且”下一次状态违规的时间戳" 值大于特定日期。

不幸的是，我不确定如何将此逻辑插入 DAX 语法中，因此任何建议将不胜感激。

多谢！ 盖尔戈

这有点棘手，但我们可以通过在度量中使用临时计算汇总表来实现：

CountStatusB =
    SUMX(
        ADDCOLUMNS(
            SUMMARIZE(
                FILTER(
                    ALL(Inventory),
                    Inventory[TimeStamp] <= MAX(Inventory[TimeStamp])
                ),
                Inventory[ID],
                "LastTimeStamp",
                MAX(Inventory[TimeStamp])
            ),
            "Status",
            LOOKUPVALUE(Inventory[Status],
                Inventory[ID], Inventory[ID],
                Inventory[TimeStamp], [LastTimeStamp])
            ),
        IF([Status] = "B",
            1,
            0
        )
    )

首先，我们创建一个汇总表来计算最后的TimeStamp对于每个ID价值。为此，我们使用SUMMARIZE过滤表上的函数，我们只考虑当天或更早的日期，分组依据ID，并计算出最大值TimeStamp.

一旦我们有了最大TimeStamp per ID今天，我们可以查一下Status是在那天，并将其作为一列添加到汇总表中。

一旦我们知道了最新的Status对于每个ID今天，我们只需要总结一下Status is "B"并忽略其他的。

如果我们将其分解为步骤，可能会更容易阅读该措施。这里的逻辑与之前相同，但为了更加清晰而使用变量。

CountB = 
    VAR CurrDay = MAX(Inventory[TimeStamp])
    VAR Summary = SUMMARIZE(
                      FILTER(
                          ALL(Inventory),
                          Inventory[TimeStamp] <= CurrDay
                      ),
                      Inventory[ID],
                      "LastTimeStamp",
                      MAX(Inventory[TimeStamp])
                  )
    VAR LookupStatus = ADDCOLUMNS(
                           Summary,
                           "Status",
                           LOOKUPVALUE(Inventory[Status],
                               Inventory[ID], Inventory[ID],
                               Inventory[TimeStamp], [LastTimeStamp]
                           )
                       )
    RETURN SUMX(LookupStatus, IF([Status] = "B", 1, 0))