替换工作表名称中的多个无效字符[关闭]

我正在写一个相当大的宏

• 最后使用用户之前输入的名称保存工作簿。
• 我为此使用了工作表的标题，因此我需要删除任何会引发文件系统错误的保留字符(/\*|?:<>").

我想避免使用大量Replace()语句，那么有没有办法在一个语句中用下划线替换多个字符 - 更像是regexp?

谢谢大家！

令人高兴的是，您会发现大多数这些字符作为工作表名称字符已经无效，即*?[] etc

但正如您已经说过的，使用regexp :)

像下面这样返回True对于有效的字符串，False对于无效的。

我已在上面添加了您的项目，并根据需要转义了特殊字符。

[更新：增加替换功能]

Sub TestCleanNames()
    Dim StrArr()
    Dim StrTst
    StrArr = Array("Am i ok", "Sheet||a", "audited??", "Sheet1")
    For Each StrTst In StrArr
        MsgBox StrTst & " = " & ValidSheetName(CStr(StrTst)) & vbNewLine & CleanSheetName(CStr(StrTst))
    Next
End Sub

有效名称函数

Function ValidSheetName(strIn As String) As Boolean
    Dim objRegex As Object
    Set objRegex = CreateObject("vbscript.regexp")
    objRegex.Pattern = "[\<\>\*\\\/\?|]"
    ValidSheetName = Not objRegex.test(strIn)
End Function

清洁功能

Function CleanSheetName(strIn As String) As String
    Dim objRegex As Object
    Set objRegex = CreateObject("vbscript.regexp")
    With objRegex
        .Global = True
        .Pattern = "[\<\>\*\\\/\?|]"
        CleanSheetName = .Replace(strIn, "_")
    End With
End Function