为什么我无法更改工作表参考？

首先，如果这个问题太明显，我提前道歉。我只是几年没有使用 VBA 和 Excel，而且在其他地方找不到我的问题的答案。

我希望我的 VBA 程序从工作表“ReportData”中获取数据，并使用它在新工作表“Report”上创建一些数据透视表。

我的问题是关于单元格引用的。我认为，只要激活或选择一个工作表，那么该工作表就成为 VBA 的参考点。因此，像 Cells(1,1).Value 这样的语句将查看活动工作表的第一个单元格中的值。但是，我不知道为什么它对我不起作用。

这是适合我的版本：

Dim PTCache As PivotCache
Dim PT As PivotTable
Dim ReportSheet As Worksheet
Dim ItemName As String
Dim Row As Long, Col As Long, i As Long
Application.ScreenUpdating = False

'Delete Report sheet if it exists
On Error Resume Next
Application.DisplayAlerts = False
Sheets("Report").Delete
On Error GoTo 0

'Add Report sheet
Set ReportSheet = Worksheets.Add
ActiveSheet.Name = "Report"

'Create Pivot Cache
Set PTCache = ActiveWorkbook.PivotCaches.Create( _
SourceType:=xlDatabase, _
SourceData:=Sheets("ReportData").Range("A1").CurrentRegion)

Row = 1
For i = 1 To 4
    For Col = 1 To 7
        ItemName = Sheets("ReportData").Cells(1, i + 2)

        With Sheets("Report").Cells(Row, Col)
            .Value = ItemName
            .Font.Size = 16
        End With
    .
    .
    .
    .
    Next Col    
Next i

我的问题是关于以下行：

With Sheets("Report").Cells(Row, Col)

为什么我需要添加

“表格（“报告”）。”

？我以为最后激活的工作表是“报告”。因此，如果我使用：

带单元格（行、列）

单独 - 不应该自动引用

工作表（“报告”）.单元格（行，列）

？ （事实并非如此）。

我还尝试在引用单元格之前激活“报告”工作表，但这也不起作用。例如，以下内容对我不起作用。它继续引用“ReportData”工作表中的单元格（这不是我想要引用的工作表）：

Dim PTCache As PivotCache
Dim PT As PivotTable
Dim ReportSheet As Worksheet
Dim ItemName As String
Dim Row As Long, Col As Long, i As Long
Application.ScreenUpdating = False

'Delete Report sheet if it exists
On Error Resume Next
Application.DisplayAlerts = False
Sheets("Report").Delete
On Error GoTo 0

'Add Report sheet
Set ReportSheet = Worksheets.Add
ActiveSheet.Name = "Report"

'Create Pivot Cache
Set PTCache = ActiveWorkbook.PivotCaches.Create( _
SourceType:=xlDatabase, _
SourceData:=Sheets("ReportData").Range("A1").CurrentRegion)

Row = 1
For i = 1 To 4
    For Col = 1 To 7
        ItemName = Sheets("ReportData").Cells(1, i + 2)

        Worksheets("Report").Activate

        With Cells(Row, Col)
            .Value = ItemName
            .Font.Size = 16
        End With
    .
    .
    .
    .
    Next Col    
Next i

第二个例子不起作用是什么？这让我发疯。我认为您所要做的就是首先激活或选择一个工作表，然后您所做的任何单元格引用都将针对您已激活或选择的工作表中的单元格。我在这里要疯了吗？

此类问题在此网站上相当常见......并且通常后面是自愿受访者的一系列评论，询问您是否正在捕获这个或那个事件、处理不同的工作簿、更改工作表名称、激活其他工作表等。关键是，没有人能确定哪里出了问题——我们或你——因为你无法控制你的对象。

VBA就像一个幼儿；对于不受控制的物体，你说：

嘿，去糖果店吧，我 5 分钟后回来……哦，还有 那些淘气的孩子其他宏家人也可能在那里。

尽管您的宝宝无疑很漂亮，但它会在淘气的步骤上花费大量时间！

我已经调整了您的代码，为您提供更多控制权，以便它不依赖于活动工作簿和工作表、选择、默认属性等。它应该让您朝着正确的方向开始......而且离那个叫糖果店的地方很远Activate.

哦，你不需要循环遍历 a 中的每个单元格Range将其值复制到新的Range，你可以将其读入Variant并写出整个Variant到新的Range.

Public Sub RunMe()
    Const DATA_SHEET_NAME As String = "ReportData"
    Const REPORT_SHEET_NAME As String = "Report"
    Dim dataSheet As Worksheet
    Dim reportSheet As Worksheet
    Dim ptCache As PivotCache
    Dim v As Variant
    Dim b As Boolean

    Application.ScreenUpdating = False

    Set dataSheet = ThisWorkbook.Worksheets(DATA_SHEET_NAME)

    'Delete Report sheet if it exists
    On Error Resume Next
    Set reportSheet = ThisWorkbook.Worksheets(REPORT_SHEET_NAME)
    On Error GoTo 0
    If Not reportSheet Is Nothing Then
        b = Application.DisplayAlerts
        Application.DisplayAlerts = False
        reportSheet.Delete
        Application.DisplayAlerts = b
    End If

    'Add Report sheet
    Set reportSheet = ThisWorkbook.Worksheets.Add
    reportSheet.Name = REPORT_SHEET_NAME

    'Create Pivot Cache
    Set ptCache = ThisWorkbook.PivotCaches.Create( _
                  SourceType:=xlDatabase, _
                  SourceData:=reportSheet.Range("A1").CurrentRegion)

    'Write the item names
    v = dataSheet.Range("C1").Resize(, 7).Value2
    With reportSheet.Range("A1").Resize(, UBound(v, 2))
        .Value = v
        .Font.Size = 16
    End With

    Application.ScreenUpdating = True

End Sub