如何通过名称获取控件名称？

我有一个简单的功能，其中有一个组合框。如果组合框的值等于“禁用”，我将禁用文本框 B。有许多组合框及其相应的文本框 B，按行排列并手动命名。如果组合框 A 被命名为Product1，文本框B将被命名Product1_status

我在想这样的事情：

If value_of_a = "disable" Then 
 Dim name_of_b as String
 name_of_b = Me.Combo.Name + "_status"
 get_object_by_name(name_of_b).Enabled = False
End If

我该怎么做呢？

我不确定你如何称呼它，但这里有一个独立的过程应该有所帮助：

Sub test()

Dim ws As Excel.Worksheet
Dim ProductCombo As OLEObject
Dim ProductText As OLEObject

Set ws = ThisWorkbook.Sheets(1)
With ws
    Set ProductCombo = .OLEObjects("Product1")
    Set ProductText = .OLEObjects(ProductCombo.Name & "_status")
    ProductText.Enabled = ProductCombo.Object.Text <> "Disabled"
End With
End Sub

编辑：我真的很讨厌工作表控件 - 每次对它们进行编程时我都从头开始！尽管如此，我想我应该添加这个子例程，根据其配对的组合框，重置名称符合 Product#_status 模式的每个文本框。该逻辑确实假设名称以 Product1、Product2 等开头，编号中没有间隙：

Sub test2()

Dim ws As Excel.Worksheet
Dim ctl As OLEObject
Dim i As Long
Dim ProductComboboxesCount
Dim ProductCombo As OLEObject
Dim ProductText As OLEObject
Const ControlPrefix As String = "Product"

Set ws = ThisWorkbook.Sheets(1)
With ws
    For Each ctl In .OLEObjects
        If TypeOf ctl.Object Is MSForms.ComboBox And Left(ctl.Name, Len(ControlPrefix)) = ControlPrefix Then
            ProductComboboxesCount = ProductComboboxesCount + 1
        End If
    Next ctl
    For i = 1 To ProductComboboxesCount
        Set ProductCombo = .OLEObjects(ControlPrefix & i)
        Set ProductText = .OLEObjects(ControlPrefix & i & "_status")
        ProductText.Enabled = ProductCombo.Object.Text <> "Disabled"
    Next i
End With
End Sub