gnuplot 边距在多图模式下如何工作？

我对 gnuplot 边距有点困惑。首先我不知道这些东西指向什么单位。它们是指向画布坐标还是画布坐标的一部分。它们在 gnuplot 模式和 multiplot 模式下的行为是否相同？

在多图模式下绘制一些数据时出现了我的问题。我正在绘制到屏幕（wtx 终端）。这么说吧，我把事情搞砸了——我从画布上得到了一些情节，或者非常小的不可读的情节。

如果没有边距，第一个图与画布顶部齐平，所以我自然想将其向下推一点。

有人可以解释 gnuplot 边距如何工作以及它们在多图模式下是否表现相同。

是的，边距在“正常”绘图模式和多重绘图模式下的行为非常相似。基本上，边距可以具有三种不同的“模式”：

1. 自动，这是默认设置。
2. 将每个边距设置为特定大小，例如set lmargin 2。单位是字符宽度（或字符高度tmargin and bmargin).
3. 设置具体的position相对于整个画布的边框，例如set lmargin at screen 0.1，它将左图边框设置为画布总宽度的 10%。

唯一的区别是multiplot模式是，1. 和 2. 中的边距参考由由layout option:

set multiplot layout 2,2

这将整个画布细分为四个大小相等的矩形。现在，使用

set lmargin 1
set rmargin 1
set tmargin 1
set bmargin 1

相对于较小的矩形，在每个子图的每一侧留下一个字符宽度或高度的边距：

set multiplot layout 2,2
set lmargin 0
set rmargin 0
set tmargin 0
set bmargin 0
set format ''
plot x
plot x**2
plot x**3
plot x**4
unset multiplot

set multiplot layout 2,2
set lmargin 1
set rmargin 1
set tmargin 1
set bmargin 1
set format ''
plot x
plot x**2
plot x**3
plot x**4
unset multiplot

如果你想设置每个边框的绝对位置，这会变得更麻烦，因为你必须为每个图设置四个边距（layout选项在这种情况下没有任何作用）：

set multiplot
set lmargin at screen 0.1
set rmargin at screen 0.47
set tmargin at screen 0.97
set bmargin at screen 0.6
plot x
...

Gnuplot 版本 5 提供了一种非常灵活的方式来生成相等的矩形，请参阅我的回答删除 gnuplot multiplot 中的空白