Clojure 中的不一致：宏中的函数和 IllegalArgumentException

以下两个在宏中使用函数的示例导致评估没有错误。

(defmacro works []
  (let [f (fn [] 1)]
    `(~f)))
(works)
;; => 1

(defn my-nullary-fn []
  (fn [] 2))
(defmacro also-works []
  (let [f (my-nullary-fn)]
    `(~f)))
(also-works)
;; => 2

However,

(defmacro does-not-work []
  (let [f (constantly 3)]
    `(~f)))
(does-not-work)

throws

java.lang.IllegalArgumentException: No matching ctor found
for class clojure.core$constantly$fn__4051 

同样地，

(defn my-unary-fn [x]
  (fn [] x))
(defmacro also-does-not-work []
  (let [f (my-unary-fn 4)]
    `(~f)))
(also-does-not-work)

throws

java.lang.IllegalArgumentException No matching ctor found
for class user$my_other_fn$fn__12802

可能是什么原因？返回的函数对象之间有区别吗fn, my-nullary-fn, constantly and my-unary-fn?

我正在运行 Clojure 1.5.1。

CLJ-946可能有关系。

看一眼clojure.lang.Compiler.ObjExpr#emitValue()。直接出现在代码（或生成的代码，在宏扩展结果的情况下）中的任何实例对象必须：

• Be 类型编译器知道如何实例化或发出引用；或者
• Have print-dup为其类型定义，在这种情况下，编译器通过读取器的往返来发出对象实例化。

函数对象确实有一个print-dup实现，但它构造的 read-eval 形式仅调用函数类构造函数的 0 参数版本：

(print-dup (fn [] 1) *out*)
;; #=(user$eval24491$fn__24492. )
(let [x 1] (print-dup (fn [] x) *out*))
;; #=(user$eval24497$fn__24498. )

Clojure 闭包是通过函数类实现的，函数类接受其封闭变量值作为构造函数参数。因此：

(let [f (fn [] 1)] (eval `(~f)))
;; 1
(let [x 1, f (fn [] x)] (eval `(~f)))
;; IllegalArgumentException No matching ctor found ...

现在您知道了，并且知道为什么要避免将函数对象直接插入到生成的代码中，即使它“有效”。