（一般）从自定义数据类型构建解析器？

我正在开发一个需要与服务器通信的网络流媒体客户端。服务器将响应编码为字节串，例如“1\NULJohn\NULTeddy\NUL501\NUL”，其中“\NUL”是分隔符。上面的响应翻译为“这是一条类型1的消息（由服务器硬编码），它告诉客户端用户的ID是什么（这里，“John Teddy”的用户ID是“501”）。

所以我天真地定义了一个自定义数据类型

data User
  { firstName :: String
  , lastName :: String
  , id :: Int
  }

以及该数据类型的解析器

parseID :: Parser User
parseID = ...

然后，在解析器成功对这样的响应进行数学运算后，只需编写一个处理程序来完成一些工作（例如，写入数据库）。这非常简单。

然而，服务器有近 100 种类似的不同响应，客户端需要解析。我怀疑一定有一种更优雅的方法来完成这项工作，而不是像这样编写 100 个几乎相同的解析器，因为毕竟所有 haksell 编码员都是懒惰的。我是通用编程的新手，所以有人可以告诉我是否有一个包可以完成这项工作？

对于这类问题我求助于仿制药-sop而不是直接使用泛型。仿制药-sop构建在泛型之上，提供以统一方式操作记录中所有字段的函数。

在这个答案中我使用ReadP附带的解析器base，但任何其他Applicative解析器就可以了。一些初步导入：

{-# language DeriveGeneric #-}
{-# language FlexibleContexts #-}
{-# language FlexibleInstances #-}
{-# language TypeFamilies #-}
{-# language DataKinds #-}
{-# language TypeApplications #-} -- for the Proxy

import Text.ParserCombinators.ReadP (ReadP,readP_to_S)
import Text.ParserCombinators.ReadPrec (readPrec_to_P)
import Text.Read (readPrec)
import Data.Proxy
import qualified GHC.Generics as GHC
import Generics.SOP

我们定义一个类型类，它可以产生Applicative它的每个实例的解析器。这里我们只定义实例Int and Bool:

class HasSimpleParser c where
    getSimpleParser :: ReadP c

instance HasSimpleParser Int where
    getSimpleParser = readPrec_to_P readPrec 0

instance HasSimpleParser Bool where
    getSimpleParser = readPrec_to_P readPrec 0

现在我们为记录定义一个通用解析器，其中每个字段都有一个HasSimpleParser实例：

recParser :: (Generic r, Code r ~ '[xs], All HasSimpleParser xs) => ReadP r
recParser = to . SOP . Z <$> hsequence (hcpure (Proxy @HasSimpleParser) getSimpleParser)

The Code r ~ '[xs], All HasSimpleParser xs约束意味着“该类型只有一个构造函数，字段类型列表为xs，并且所有字段类型都有HasSimpleParser实例”。

hcpure构造一个 n 元乘积 (NP）其中每个组件都是相应字段的解析器r. (NPproducts 将每个组件包装在类型构造函数中，在我们的例子中是解析器类型ReadP).

然后我们使用hsequence将解析器的 n 元乘积转换为 n 元乘积的解析器。

最后，我们 fmap 到结果解析器中，并将 n 元乘积转回原始值r记录使用to. The Z and SOP需要构造函数将 n 元乘积转换为乘积和to函数期望。

好的，让我们定义一个示例记录并将其作为一个实例Generics.SOP.Generic:

data Foo = Foo { x :: Int, y :: Bool } deriving (Show, GHC.Generic)

instance Generic Foo -- Generic from generics-sop

让我们检查一下是否可以解析Foo with recParser:

main :: IO ()
main = do
    print $ readP_to_S (recParser @Foo) "55False"

结果是

[(Foo {x = 55, y = False},"")]