银联商务MISPOS接口开发demo 需要调用POSINF.DLL

//外部函数声明
FUNCTION long bankall(string as_request, ref string as_response) LIBRARY "posinf.dll"




//调用
string    ls_content,ls_sellway,ls_money,ls_OldDate
string   ls_posid,ls_casher,ls_rand
dec{2}   ldec_needpay, ldec_pay,ldec_consume
dec{2}   ldec_cnt,ldec_payed
string    ls_cardid,ls_voucher,ls_consume
string    ls_info,ls_refno,ls_OldRefno,ls_OldVoucher


//'00'－消费'01'－撤消'02'－退货'03'－查余额'04'－重打印'05'－签到'06'－结算'07'－重打结算单
ls_sellway=left(sle_type.text,2)
if pos('00/01/02/03/04/05/06/07',ls_sellway)=0 then 
    messagebox('提示','请录入正确的交易类型！')
    sle_type.setfocus()
    sle_type.selecttext(1,len(sle_type.text))
    return
end if


///交易金额
if ls_sellway='00' or ls_sellway='01' or ls_sellway='02' then 
    //'00'－消费'01'－撤消'02'－退货
    ldec_needpay=abs(dec(sle_payamt.text))
    if ldec_needpay=0 or (not IsNumber(sle_payamt.text)) then
        messagebox('提示','请录入金额！')
        sle_payamt.setfocus()
        sle_payamt.selecttext(1,len(sle_payamt.text))
        return
    end if      
else
    ldec_needpay=0
end if


//'02'－退货//原交易日期、原交易参考号    
if ls_sellway='02' then 
    ls_OldDate=trim(sle_date.text)
    if isnull(ls_OldDate) or ls_OldDate='' or len(ls_OldDate)<>8 then 
        messagebox('提示','请录入原交易日期(8位)，格式为yyyymmdd！')
        sle_date.setfocus()
        sle_date.selecttext(1,len(sle_date.text))
        return
    end if
    
    ls_OldRefno=trim(sle_refno.text)
    if isnull(ls_OldRefno) or ls_OldRefno='' or len(ls_OldRefno)<>12 then 
        messagebox('提示','请录入原交易参考号(12位)！')
        sle_refno.setfocus()
        sle_refno.selecttext(1,len(sle_date.text))
        return
    end if
    
else
    ls_OldDate=space(8)
    ls_OldRefno=space(12)
end if


//'01'－撤消//原凭证号
if ls_sellway='01' then 
    ls_OldVoucher=trim(sle_voucher.text)
    if isnull(ls_OldVoucher) or ls_OldVoucher='' or len(ls_OldVoucher)<>6 then 
        messagebox('提示','请录入原凭证号(6位)！')
        sle_voucher.setfocus()
        sle_voucher.selecttext(1,len(sle_date.text))
        return
    end if
else
    ls_OldVoucher=space(6)
end if


ls_posid='99'
ls_casher='1001'
ls_money=string(round(ldec_needpay,2)*100,'000000000000')
ls_rand=string(rand(999),'000') ///3位随机数字
//传给银行卡刷卡系统的交易请求文件：
//POS机号(8位,不足右补空格)+POS员工号(8位,不足右补空格)+交易类型标志(2位)+金额(12位,不足左补0)+
//原交易日期(8位，yyyymmdd格式，退货时用，其他交易空格)
//原交易参考号(12位,退货时用，其他交易空格)
//原凭证号(6位,撤消时用，其他交易空格)
//备用(000000)+LRC(3位随机数字)
ls_content=ls_posid+space(8 - len(ls_posid)) +ls_casher+space(8 - len(ls_casher)) +ls_sellway+ls_money+&
+ls_OldDate+ls_OldRefno+ls_OldVoucher+'000000'+ls_rand


ls_info=space(300)
bankall(ls_content,ls_info)


if left(ls_info,2)='00' then     //响应码2位, 00 表示成功，其它表示失败
    ls_cardid =mid(ls_info,7,20)  //卡号20位    
    ls_voucher=mid(ls_info,27,6)   //凭证号6位
    ls_consume=mid(ls_info,33,12)  //金额12位    
    ls_refno  =mid(ls_info,124,12)  //交易参考号12
    messagebox('提示',"交易成功，金额为"+string(dec(ls_consume)/100)+"，~r~n凭证号是："+ls_voucher+"，交易参考号是："+ls_refno)
else
    messagebox('提示',"交易失败，返回值："+left(ls_info,2)+"，失败原因："+mid(ls_info,45,40))
    return 
end if